**Program 18.5.1** SAS Code for Two Sample Log-Rank Tests for Survival Data

%macro SS\_TwoSmpleLogRank(

Accrual =, /\* accrual period \*/

Follow =, /\* additional follow-up period \*/

inR =, /\* group allocation proportion(a1, a2) \*/

inLambda =, /\* hazard rates under the alternative \*/

alpha =, /\* alpha \*/

power =, /\* power \*/

sides = /\* 1: One-sided test 2: Two-sided test \*/

);

proc iml;

%let K = 2; r = &inR; Group = J(&K,1,0); lambda = &inLambda;

delta = lambda[2]/lambda[1]; d\_prob = J(&K, 1,0);

n = J(&K, 1,0); D = J(&K, 1,0);

do i=1 to &K;

group[i] = i;

d\_prob[i]=1-(exp(-lambda[i]\*&Follow))\*(1-exp(-lambda[i]\*&Accrual))

/(&Accrual\*lambda[i]);

end;

z\_p1=1-&alpha/&sides; z\_alpha = probit(z\_p1);

z\_p2=&power; z\_beta = probit(z\_p2);

Total = int((1/(r[1]\*d\_prob[1])+1/(r[2]\*d\_prob[2]))\*((z\_alpha+z\_beta)/log(delta))\*\*2)+1;

do i=1 to &K; n[i]= r[i]\*Total; D[i]= d\_prob[i]\*n[i]; end;

print ' Sample Size Calculation';

print 'for Two Sample Log Rank Test for Survival Data';

Accrual=&Accrual; Follow\_Up= &Follow;

print 'Accrual Period : ' &Accrual;

print ' Follow Up period : ' &Follow;

print Group lambda delta r d\_prob;

print Group n D;

print Total;

quit;

run;

%mend SS\_TwoSmpleLogRank;

/\*-------------- Run the macro for Example 18.5.1 ----------------------------\*/

%SS\_TwoSmpleLogRank(

Accrual =3, /\* accrual period \*/

Follow =2, /\* additional follow-up period \*/

inR =%str({0.3, 0.7}), /\* group allocation proportion(r1, r2)\*/

inLambda =%str({0.231, 0.154}), /\* hazard rates under the alternative \*/

alpha =0.05, /\* alpha \*/

power =0.9, /\* power \*/

sides =2 /\* two-sided test \*/

);